" DrChip's debugger syntax file
" Language   : DrChip's debugger output file
" Maintainer : Charles E. Campbell, Jr.
" Last change: Mar 25, 2006
" Version    : 2

" allows usual C characters plus the : for C++
set iskeyword=@,:,48-57,_,192-255

" Remove any old syntax stuff hanging around
syn clear

" Delimiters, strings, numbers
syn match   dbgDelimiter			"[{}]$"
syn match   dbgDelimiter			","
syn region  dbgAngleBrkt				oneline	matchgroup=Green   start="\w<"lc=1	 matchgroup=Green end=">"	contains=dbgNotify,dbgAngleBrktInc,dbgString,dbgWarning
syn region  dbgAngleBrktInc		contained	oneline		 		 start="<"		end="\ze>\([ \t,)=]\|$\)"	contains=dbgNotify,dbgAngleBrktInc,dbgString,dbgWarning
syn region  dbgString					oneline	matchgroup=Blue start='"'	matchgroup=Blue end='"'		contains=dbgNotify,dbgWarning,@Spell
syn match   dbgNumber				"\<-\=[0-9]\+\>"
syn match   dbgNumber				"\<-\=[0-9]\+\ze:"
syn match   dbgNumber				"\<=-\=[0-9a-fA-F]\+\>"
syn match   dbgNumber				"\<[0-9a-fA-F]\+x$"
syn match   dbgNumber				"\<[0-9a-fA-F]\+x[^a-zA-Z=]"me=e-1
syn match   dbgNumber				"\d\+x\d\+"

" Let me see errors/warnings/severe messages easily
syn keyword dbgNotify				fatal error severe
syn match   dbgNotify				"!!!\|???"
syn keyword	dbgWarning				warning perror

" Bars, Function names, Return
syn match   dbgFunction		contained	"\~\=[a-zA-Z_][a-zA-Z0-9_]*"
syn match   dbgFunction		contained	"[a-zA-Z_][a-zA-Z0-9_]*::\~\=[a-zA-Z_][a-zA-Z0-9_]*"
syn match   dbgBar				"^|\+"
syn match   dbgStartFunc			"^|*\~\=[a-zA-Z_][a-zA-Z0-9_]*("						contains=dbgBar,dbgFunction,dbgDelimStart
syn match   dbgStartFunc			"^|*[a-zA-Z_][a-zA-Z0-9_]*::\~\=[a-zA-Z_][a-zA-Z0-9_]*("		contains=dbgBar,dbgFunction,dbgDelimStart
syn match   dbgStartFunc			"^|*[a-zA-Z_][a-zA-Z0-9_]*::\~\=operator\s*[-^|=+/<>[][<>\]]\=("	contains=dbgBar,dbgFunction,dbgDelimStart
syn match   dbgStopFunc				"^|\+\%(longjmp \)\=return \~\=[a-zA-Z_][a-zA-Z0-9_]*"					contains=dbgBar,dbgFunction
syn match   dbgStopFunc				"^|\+\%(longjmp \)\=return [a-zA-Z_][a-zA-Z0-9_]*::\~\=[a-zA-Z_][a-zA-Z0-9_]*"	contains=dbgBar,dbgFunction
syn match   dbgComment				"^[ \t]*#.*$"									contains=@Spell
syn match   dbgMatrix				"^|[-+ 0-9.e]\+|$"								contains=dbgMatrixBar
syn match   dbgMatrixBar	contained	"|"

" Problems
syn keyword dbgProblem	PROBLEM[:]	COMBAK[:]	WARNING[:]	SEVERE[:]	NOTE[:]	DIFFER[S:]
syn match   dbgProblem '\s<--\s'

" OK
syn keyword dbgOk		OK

if !exists("did_drchip_dbg_syntax")
  let did_drchip_dbg_syntax= 1

  " Links
  hi link dbgAngleBrktInc	dbgAngleBrkt

  " If the "Warning" highlighting group hasn't been defined,
  " then this script will define it.
  fun! s:HLTEST(hlname)
    let id_hlname= hlID(a:hlname)
    let fg_hlname= synIDattr(synIDtrans(hlID(a:hlname)),"fg")
    if id_hlname == 0 || fg_hlname == 0 || fg_hlname == -1
     return 0
    endif
    return 1
  endfun
  if !s:HLTEST("Warning")
   hi Warning term=NONE cterm=NONE gui=NONE ctermfg=black ctermbg=yellow guifg=black guibg=yellow
  endif
  delf s:HLTEST

  hi link dbgAngleBrkt		String
  hi link dbgComment		Comment
  hi link dbgDelimiter		Delimiter
  hi link dbgMatrixBar		Delimiter
  hi link dbgFunction		Statement
  hi link dbgNotify		Error
  hi link dbgWarning		Warning
  hi link dbgNumber		Number
  hi link dbgProblem		Error
  hi link dbgString		String
  hi link dbgOK			Special
  hi link dbgTabTitle		Title
  hi link dbgTabTitleSep	Delimiter

  " override
  hi link Function	Cyan

  " New Stuff
  hi link dbgBar		Magenta
endif
" vim: ts=6